Articles · Progress ABL

Vérification de syntaxe Progress 4GL ABL dans Sublime Text

Publié le · Mis à jour le

Si vous éditez (ou aimeriez éditer) vos programmes Progress 4GL ABL avec l’excellent éditeur Sublime Text, vous perdez la fonction « Check syntax » de Progress OpenEdge Architect.

Voici comment retrouver cette fonctionnalité dans Sublime Text ! Suivez les instructions de la page GitHub de notre projet, ou lisez la suite.

Créez un fichier nommé syntax.p avec le contenu suivant :

/* Progress Check Syntax by Gabriel Hautclocq */
/* How to use it : C:\Progress\102B\bin\_progres.exe -1 -b -pf C:\Progress\102B\startup.pf -p C:\path\to\syntax.p -param "C:\program_to_check.p" */

DEFINE VARIABLE ch_prog AS CHARACTER NO-UNDO.
DEFINE VARIABLE ch_mess AS CHARACTER NO-UNDO.
DEFINE VARIABLE i       AS INTEGER   NO-UNDO.

/* Extracts the parameters */
ASSIGN ch_prog = ENTRY( 1, SESSION:PARAMETER ).
IF NUM-ENTRIES(SESSION:PARAMETER) >= 2 THEN DO :
  ASSIGN PROPATH = PROPATH + ":" + ENTRY( 2, SESSION:PARAMETER ).
END.

/* Compile without saving */
COMPILE VALUE( ch_prog ) SAVE=NO NO-ERROR.

/* If there are compilation messages */
IF COMPILER:NUM-MESSAGES > 0 THEN DO:

  ASSIGN ch_mess = "".

  /* For each messages */
  DO i = 1 TO COMPILER:NUM-MESSAGES:

    /* Generate an error line */
    ASSIGN ch_mess =
      SUBSTITUTE( "&1 File:'&2' Row:&3 Col:&4 Error:&5 Message:&6",
        IF COMPILER:WARNING = TRUE THEN "WARNING" ELSE "ERROR",
        COMPILER:GET-FILE-NAME  ( i ),
        COMPILER:GET-ROW        ( i ),
        COMPILER:GET-COLUMN     ( i ),
        COMPILER:GET-NUMBER     ( i ),
        COMPILER:GET-MESSAGE    ( i )
      )
    .

    /* display the message to the standard output */
    PUT UNFORMATTED ch_mess SKIP.
  END.
END.
ELSE DO :

  /* display to the standard output */
  PUT UNFORMATTED "SUCCESS: Syntax is Correct." SKIP.
END.

/* End of program */
QUIT.

Il vous faut ensuite un fichier de build pour Sublime Text. Créez un fichier nommé « ABL.sublime-build » dans « C:\Users\<votre utilisateur>\AppData\Roaming\Sublime Text 3\Packages\User » avec le contenu suivant :

{
  "shell_cmd": "C:\\Progress\\102B\\bin\\_progres.exe -1 -b -pf C:\\Progress\\102B\\startup.pf -p C:\\path\\to\\syntax.p -param \"$file\"",
  "file_regex": "^(?:ERROR|WARNING]) File:'(.+)' Row:([0-9]+) Col:([0-9]+) Error:[0-9]+ Message:(.*)$"
}

Et voilà ! Relancez Sublime Text : vous pouvez maintenant vérifier la syntaxe avec CTRL + B !

Tous les articles